Cat-sat-val type for matrix core?

I am adding non-scopal adverbs and (non-case-marking an non-info-structure) adpositions to the GM – to support wh-questions, but I was thinking of actually adding support for simple declarative sentences involving them, too (simply because I have them in my development grammar and some simple support shouldn’t be hard to add).

For my Russian development grammar, I ended up needing the following kind of head-adjunct phrase:

my-head-adj-phrase := head-adj-int-phrase & 
 [ HEAD-DTR.SYNSEM [ LOCAL.CAT.VAL [ SPR < >, SUBJ < >, COMPS < > ],
                     NON-LOCAL.SLASH 0-dlist ],
    NON-HEAD-DTR.SYNSEM [ NON-LOCAL.QUE 0-dlist,
    					  LOCAL.CAT.VAL  [ SPR < >, SUBJ < >, COMPS < > ] ] ].

As for the nonlocal constraints, this is what I need for my test suite so far; I am not yet sure whether more will be needed.

Right now I have a question about the VAL constraints. I seem to be needing them because without them I get lots of trees. I realize adpositions and adverbs can attach on different levels but the structure I am considering right now is when they attach to S. I cannot use the (relatively new) cat-sat type because the NON-HEAD-DTR has a non-empty MOD. Should I then do the following (on the matrix core level):

cat-val-sat := cat & 
 [ VAL [ SPR olist,
         SPEC olist,
         COMPS olist,
         SUBJ olist ] ].

cat-sat := cat-val-sat &
 [ HEAD.MOD olist ].

?

Yes, that’s a fine type to create, but you don’t want to put it on the head-daughter of the rule and probably not on the non-head daughter either. For the head daughter, this can be a constraint on the MOD value of the modifier — so they can specify if they want to attach to V, VP or S (or ambiguously any of those) and the same rule can work for modifiers of different values. Also, to get the LBL sharing right in non-scopal modifiers of nominal projections, the modifier needs to attach to the SPR non-empty constituent.

For the non-head (i.e. modifier) daughter, you probably just want COMPS < >. The SPR value on modifiers is used for degree specifiers (like very in very sleepy), but that doesn’t have to be saturated. Similarly, adps might take subjects in a copulaless language but can function as modifiers without them (maybe only without them).

1 Like

Actually, I think I have been misunderstanding the meaning of cat-sat (and of the list hierarchy, yet again).

cat-sat means things like SPR and COMPS are olist which for some reason I thought meant empty list. But it doesn’t does it?

If I specify the preposition’s complement as cat-sat, that does not help me get rid of the tree on the left, for example (this is Ivan is lying in the book again):

21%20PM

So, this does not help with the first tree:

norm-adposition-lex := norm-sem-lex-item & basic-intersective-mod-lex & 
  [ SYNSEM [ LOCAL [ CAT [ HEAD adp,
                           VAL.COMPS < [ LOCAL [ CAT cat-sat & [ HEAD noun ],
                                                 CONT.HOOK.INDEX #ind ],
                                         NON-LOCAL.QUE #que ] > ],
                     CONT.RELS <! [ PRED #pred, ARG0 event, ARG1 event ] !> ],                            
             LKEYS.KEYREL arg12-ev-relation & [ PRED #pred, ARG2 #ind ],
             NON-LOCAL.QUE #que ] ].

But this does:

norm-adposition-lex := norm-sem-lex-item & basic-intersective-mod-lex & 
  [ SYNSEM [ LOCAL [ CAT [ HEAD adp,
                           VAL.COMPS < [ LOCAL [ CAT [ HEAD noun, VAL.SPR < > ],
                                                 CONT.HOOK.INDEX #ind ],
                                         NON-LOCAL.QUE #que ] > ],
                     CONT.RELS <! [ PRED #pred, ARG0 event, ARG1 event ] !> ],                            
             LKEYS.KEYREL arg12-ev-relation & [ PRED #pred, ARG2 #ind ],
             NON-LOCAL.QUE #que ] ].

Indeed! olist means that the list might be non-empty, but if it is non-empty, then every element on it is [ OPT + ]. I’m actually not sure off the top of my head what cat-sat was created for, but you’re right that it won’t do what you want here. Your solution (SPR < > on the complement) is what I would do.