Determiner extraction rule and agreement

Related to this and this

Here’s my current determiner extraction rule:

extracted-det-phrase := basic-extracted-arg-phrase & head-compositional &
  [ C-CONT [ RELS.LIST < >,
             HCONS.LIST < >,
             ICONS.LIST < >,
             HOOK #hook ],
    SYNSEM.LOCAL [ CAT [ VAL [ SUBJ < >,
                               COMPS < >,
                               SPR < > ] ],
                   CONT.HOOK #hook ],
    HEAD-DTR.SYNSEM [ L-PERIPH -,
                      LOCAL.CAT.VAL.SPR < gap &
                                          [ LOCAL local ] > ] ].

I seem to be losing the noun-determiner agreement here, however; the VAL feature on the SLASH-ed element ends up being valence-min. This results in the extracted determiner happily filling the gap regardless of what the original agreement in CASE and PNG was between the noun and the determiner.

Any ideas on what to do here? I had a somewhat convoluted solution to that described here but I don’t think it is correct because it breaks here.

The determiner extraction rule should match (aspects of) the SYNSEM of the gap’s SPEC with the SYNSEM of the head daughter. As for which aspects, look to the head-spec rule to see what’s matched there.

1 Like

Finally found it! I thought this was what my rule was doing but of course it was constraining the determiner’s own (presumably meaningless) values.

I am having a bit of further trouble with this rule. (It’s a bit mysterious because have this impression that it worked before and I didn’t really change anything, but oh well, here it is):

extracted-det-phrase := basic-extracted-arg-phrase & head-compositional &
  [ C-CONT [ RELS.LIST < >,
             HCONS.LIST < >,
             ICONS.LIST < >,
             HOOK #hook ],
    SYNSEM.LOCAL [ CAT [ VAL [ SUBJ < >,
                               COMPS < >,
                               SPR < > ],
                         HEAD.CASE #case ],
                   CONT.HOOK.INDEX.PNG #png ],
    HEAD-DTR.SYNSEM [ L-PERIPH -,
                      LOCAL.CAT.VAL.SPR < gap &
                                           [ LOCAL #local & local & [ CONT.HOOK #hook,
                                                    CAT [ HEAD det,
                                                          VAL.SPEC.FIRST [ CAT.HEAD.CASE #case,
                                                                           CONT.HOOK.INDEX.PNG #png ] ] ] ] >,
                      NON-LOCAL.SLASH.LIST < #local > ] ].

In sentences like (1):

Kakuju Ivan  chitaet knugy?
which  Ivan  reads  book
Which book is Ivan reading? [rus]

The unification failure at the level of the filler-gap rule is between synsem-min and local-min at the determiner’s SPEC, ARGS.FIRST.LOCAL.CAT.VAL.SPEC:

Screen Shot 2020-04-17 at 4.14.58 PM

I am pretty sure I’ve seen this before and it was something silly but I cannot figure out now…

Is the value of SPEC a local or a synsem?

It appears to be a synsem but I am not sure where this comes from; there is nothing overt like that that I can see…

The def of basic-determiner-lex assumes it’s a synsem.

basic-determiner-lex := no-ltop-lex-item &
  [ SYNSEM [ LOCAL [ CAT [ HEAD det,
			   VAL.SPEC.FIRST.LOCAL.CONT.HOOK [ INDEX #ind,
							    LTOP #larg ]],
		     CONT [ HCONS <! qeq &
				   [ HARG #harg,
				     LARG #larg ] !>,
			    RELS <! relation !> ] ],
	     LKEYS.KEYREL quant-relation &
		   [ ARG0 #ind,
		     RSTR #harg ] ] ].

But in your rule you have SPEC.FIRST [ CAT, meaning you’re assuming it’s a local object.

Ah! Thank you! Indeed, I lost the LOCAL part of the path there.

I was not aware that such shortcuts are possible and meaningful, actually, or wasn’t fully realizing it, anyway.

How does this work exactly? If I say something is simply [ CAT.HEAD noun ], that means it is of type local-min (because cat is appropriate for local-min)?

Yes, exactly. It’s not a shortcut so much as a well-formedness constraint, though.

1 Like