LIGHTness in bare NPs

I currently cannot attach a focus particle to a wh-word because my wh-word is [ LIGHT + ] and the particle from the infostructure library says its MOD is [ LIGHT - ]. I see in Sanghoun’s thesis that [LIGHT + ] indicates a “word” while [ LIGHT - ] a phrase. I am not sure what that means. Is a bare NP like who a word or a phrase? For some reason which I am still investigating, my who NP is [ LIGHT + ] but Ivan NP is [ LIGHT - ].

Does your wh pronoun go through a bare-np rule? That might be what’s making the difference…

Both Ivan and who are bare NPs in my two test sentences (who FOC arrived? Ivan FOC arrived). There is the difference that Ivan first goes through a lexical rule while who.NOM is fullform in the lexicon.

Oh, I think I see what you mean. who appears as a NP but it didn’t actually go through it! How do I make it to?.. Or should I hardcode [LIGHT - ] for it in the lexicon?

Something in here apparently means the word is of type lex-xynsem which is [ LIGHT + ]. I can’t trace it yet though:

wh-word-lex := norm-hook-lex-item & basic-icons-lex-item &
  [ SYNSEM [ LOCAL [ CAT.VAL [ SPR < >,
                               SUBJ < >,
                               COMPS < >,
                               SPEC < > ],
                     CONT [ RELS.LIST < [ LBL #larg,
                                          ARG0 #arg0 ],
                                        [ PRED "which_q_rel",
                                          ARG0 #arg0,
                                          RSTR #harg ] >,
                            HCONS.LIST < [ HARG #harg,
                                           LARG #larg ] > ] ],
             NON-LOCAL.QUE.LIST < #arg0 >,
             L-QUE + ] ].

wh-pronoun-noun-lex := wh-word-lex & non-mod-lex-item & zero-arg-que &
  [ SYNSEM [ LOCAL [ CAT.HEAD noun,
                   CONT [ RELS.LIST < [ ARG0 ref-ind ],
                                      [ ] >,
                          HOOK.INDEX.PNG.PER 3rd ] ],
              LIGHT - ] ].

You don’t want the wh pronouns to go through bare-np because they already have their quantifiers (which_q_rel); giving them a non-empty SPR value would mean they have to go through bare-np, and then they’d get a second quantifier (exist_q_rel), which would mean broken MRSes.

You’re right that lex-synsem is likely the culprit. As for figuring out where it’s coming from, I suggest using the LKB to look at the expanded type for each of those supertypes. One or more will (probably) have [ SYNSEM lex-synsem ] and then you can trace backwards from those to see whose introducing it.

OK, here’s what I did:

  1. Looked at expanded type in the LKB starting from wh-pronoun-noun-lex and then each of the supertypes in turn, for as long as I was seeing lex-synsem in the type: wh-word-lex, norm-hook-lex-item, norm-ltop-lex-item.
  2. norm-ltop-lex-item is still a lex-synsem while its supertype is lex-item and that one is a synsem.

Does this mean norm-ltop-lex-item is the “culprit”?

norm-ltop-lex-item := lex-item &
  [ SYNSEM [ LOCAL.CONT [ HOOK [ LTOP #ltop ],
                          RELS.LIST.FIRST #keyrel ],
             LKEYS.KEYREL #keyrel & [ LBL #ltop ] ] ].

How do I deal with it now? If I simply copy the same constraints, I imagine the effect will be still that my wh-pronoun will remain a lex-synsem. But then the constraints are meaningful (in the area which I still don’t fully understand).

I re-created the type for wh-word without using norm-hook and norm-ltop lex-item types, copying all the same constraints manually:

wh-word-lex := basic-icons-lex-item &
  [ SYNSEM [ LOCAL [ CAT.VAL [ SPR < >,
                               SUBJ < >,
                               COMPS < >,
                               SPEC < > ],
                     CONT [ HOOK [ INDEX #arg0,
                                   LTOP #larg ],
                            RELS.LIST < #keyrel & [ LBL #larg,
                                          ARG0 #arg0 ],
                                        [ PRED "which_q_rel",
                                          ARG0 #arg0,
                                          RSTR #harg ] >,
                            HCONS.LIST < [ HARG #harg,
                                           LARG #larg ] > ] ],
             NON-LOCAL.QUE.LIST < #arg0 >,
             L-QUE +,
             LKEYS.KEYREL #keyrel ] ].

This of course is still a lex-synsem, as it is the same structure. But without the LTOP-KEYREL identities, I do not get the pronoun relations.

After further conversation with @ebender, it looks like what should be changed here is not the wh-word but instead the particle. A particle of this sort attaches to words, not phrases, so it should require MOD < [ LIGHT + ] >.