Losing my RELS in 2P analyses


#1

I’ve modified how I define my 2nd position elements and suddenly my RELS are disappearing when they go through head-comp and head-subj rules. Any help would be appreciated (I have well exceeded the “10 minute rule”).

Here is the definition of my 2nd position enclitics, which carry tense and mood information. They take a complement to their left, and inherit that complement’s arguments.

2p-lex := lex-item & 
  [ SYNSEM [ LOCAL.CAT [ HEAD verb & [ AUX +,
                            MOD < >,
                            PRD + ],
           VAL [ SUBJ < #subj >,
                 COMPS < #comps . #vcomps >,
                 SPR < >,
                 SPEC < > ]]],
    ARG-ST < #subj &
       [ LOCAL [ CAT [ HEAD noun,
           VAL [ COMPS < > ]],
           CONT.HOOK.INDEX #xarg ]],
       #comps &
       [ OPT -,
         LOCAL [ CAT [ VAL [ SUBJ < #subj >,
                             COMPS #vcomps ],
                       HEAD [ PRD +,
                              FORM nonfinite ],
                       POSTHEAD - ],
                 CONT.HOOK.XARG #xarg ]] > ].

mood-strong-real-verb-lex := 2p-lex &
  [ SYNSEM.LOCAL.CAT.VAL.COMPS.FIRST.LOCAL.CONT.HOOK.INDEX.E.MOOD strong-real ].

3-aux-verb-lex := 2p-lex &
  [ SYNSEM.LOCAL.CAT.VAL.COMPS.FIRST.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG.PER 3rd ].

mood-strong-real-3-verb-lex := mood-strong-real-verb-lex & 3-aux-verb-lex.

These can then go through my head-comp rule, and comp-head and comp-subj rules. These rules are basic out-of-the-grammar-matrix rules, with very little extra, e.g.:

comp-head-phrase := basic-head-1st-comp-phrase & head-final-head-nexus.

head-subj-phrase := decl-head-subj-phrase & head-initial-head-nexus &
  [ NON-HEAD-DTR.SYNSEM.LOCAL.CAT.HEAD.PRD -,
    SYNSEM.LOCAL.CAT.VAL.COMPS phlist ].

head-comp-phrase := basic-head-1st-comp-phrase & head-initial-head-nexus &
[ SYNSEM.LIGHT -,
HEAD-DTR.SYNSEM.LOCAL.CAT.VAL.COMPS phlist ].

(phlist is a type of list that is either POSTHEAD + or empty.)

These rules generate the right trees but I’m noticing that the semantics of complements and subjects gets lost when going through head-comp and head-subj. Any help would be appreciated.


#2

Interestingly, the lexical analysis, which is preserved for null-marked phrases, does pick up the RELS of the subject. (It is still losing the RELS of the head-comp rule, however.) For comparison, here is the lexical rule. I am stumped as to why this is picking up subject information but the second position element is not:

neutral-3rd-pred-lex-rule := local-change-only-lex-rule & same-agr-lex-rule & same-ctxt-lex-rule &
  [ SYNSEM [ LOCAL [ CAT [ HEAD verb &
                             [ AUX +,
                               PRD +,
                               MOD < >,
                               FORM finite ],
                           VAL [ SUBJ < #subj & [ LOCAL.CONT.HOOK.INDEX.PNG.PER 3rd ] >,
                                 COMPS #comps,
                                 SPR #spr,
                                 SPEC #spec ]],
                     CONT [ HOOK [ GTOP #gtop,
                                   LTOP #ltop,
                                   INDEX #index & [ E.MOOD neutral ],
                                   XARG #xarg,
                                   ICONS-KEY #ikey,
                                   CLAUSE-KEY #ckey ],
                            RELS #rels,
                            HCONS #hcons,
                            ICONS #icons ]]],
    DTR [ INFLECTED infl-satisfied,
         SYNSEM.LOCAL [ CAT [ HEAD [ PRD +,
                                    FORM nonfinite ],
                                VAL [ SUBJ < #subj >,
                                      COMPS #comps,
                                      SPR #spr,
                                      SPEC #spec ]],
                       CONT [ HOOK [ GTOP #gtop,
                                     LTOP #ltop,
                                     INDEX #index,
                                     XARG #xarg,
                                     ICONS-KEY #ikey,
                                     CLAUSE-KEY #ckey ],
                              RELS #rels,
                              HCONS #hcons,
                              ICONS #icons ]]]].

#3

Could this be relevant?

http://moin.delph-in.net/GeFaqMissingRels


#4

Yes I noticed this on the neutral-3rd-pred-lex-rule after I sent it. Adding the following:

C-CONT [ RELS <!  !>,
         HCONS <!  !> ] ]

Fixes it for all parses. But there’s no C-CONT on a lex-item and so I’m not sure why those are dropping items from the RELS list.


#5

I added an empty SYNSEM.LOCAL.CONT.RELS <! !> to the 2p-lex and that seems to have fixed it, though still thinking of more tests (I need some more basic sentences in my test suite). So I think that may have done it - thanks Olga.