# Relations lost in adjunct extraction with alists (emerson lists)

**URL:** <https://delphinqa.ling.washington.edu/t/relations-lost-in-adjunct-extraction-with-alists-emerson-lists/373>\
**Category:** DELPH-IN JRF\
**Tags:** append-list\
**Created:** [November 20, 2019, 6:58pm UTC](https://delphinqa.ling.washington.edu/t/relations-lost-in-adjunct-extraction-with-alists-emerson-lists/373 "2019-11-20T18:58:34Z")\
**Posts on this page:** 18\
**Page:** 1

<div class="post-metadata">

**Author:** ![olzama](https://delphinqa.ling.washington.edu/user_avatar/delphinqa.ling.washington.edu/olzama/32/6_2.png) [@olzama](https://delphinqa.ling.washington.edu/u/olzama)\
**Post date:** [November 20, 2019, 6:58pm UTC](https://delphinqa.ling.washington.edu/t/relations-lost-in-adjunct-extraction-with-alists-emerson-lists/373/1 "2019-11-20T18:58:34Z")

</div>

Here’s another question about how to use @guyemerson’s append lists ([here’s the first question about that](https://delphinqa.ling.washington.edu/t/emerson-append-lists-for-subject-extraction/372/2)).

```auto
(1) Куда идет Иван?
    Kuda idet Ivan?
    where go.3SG.PRES Ivan.NOM
    `Where does Ivan go?' [rus]

```

![48%20AM](https://delphinqa.ling.washington.edu/uploads/default/original/1X/26174f0d6f003576a52742e9369cb9a87f443133.png)

The adjunct extraction rule below, which uses alists instead of diff-lists, applies without a unification failure to an S, and so I get a parse for sentences like (1).

```auto
extracted-adv-adp-adj-phrase := basic-extracted-adj-phrase &
  [ SYNSEM [ LOCAL.CAT [ POSTHEAD #ph,
                         MC #mc ],
             NON-LOCAL.SLASH 1-alist & [ LIST < [ CAT [ HEAD +rp &
                                                       [ MOD < [ LOCAL intersective-mod &
                                                                       [ CAT [ HEAD #head,
                                                                               VAL #val,
                                                                               POSTHEAD #ph,
                                                                               MC #mc ],
                                                                         CONT.HOOK #hook,
                                                                         CTXT #ctxt ] ] > ],
                                                  VAL [ SUBJ olist,
                                                        COMPS olist,
                                                        SPR olist ] ] ] > ] ],
    HEAD-DTR.SYNSEM canonical-synsem &
                    [ LOCAL local &
                            [ CAT [ HEAD verb & #head,
                                    VAL #val &
                                        [SUBJ < >],
                                    POSTHEAD #ph,
                                    MC #mc ],
                              CONT.HOOK #hook,
                              CTXT #ctxt ],
                      NON-LOCAL.SLASH 0-alist,
                      MODIFIED notmod ],
    C-CONT [ HOOK #hook,
             HCONS.LIST < >,
             ICONS.LIST < > ] ].

```

However, I lose the relations: in the resulting MRS, I only have relations associated with the adverb (_in which place_). The semantics of _Kim goes_ is lost.

 ![42%20AM](https://delphinqa.ling.washington.edu/uploads/default/original/1X/7928de663c13684a115b8f37be17f1204aeec8d5.png)

Inspecting the local AVMs for the S-subtree doesn’t immediately show anything alarming (like it would with diff-lists):

 ![36%20AM](https://delphinqa.ling.washington.edu/uploads/default/original/1X/24e47dba805e3cf30fea4861cd24d5d250d45946.png)

 ![23%20AM](https://delphinqa.ling.washington.edu/uploads/default/original/1X/9f1cd7e363d0c54e7aac0864ffeec7ebfacdd0ce.png)

lower VP (intransitive verb):

 ![33%20AM](https://delphinqa.ling.washington.edu/uploads/default/original/1X/bfa6d77c73b8eda636a06c00c55542fc742b1909.png)

 ![41%20AM](https://delphinqa.ling.washington.edu/uploads/default/original/1X/51c249299f6579d98199e5a8f5dd9783f9c3f78b.png)

In terms of the diff-lists, these look “healthy”. Of course they aren’t diff-lists so I don’t really know. Any feedback?

---

<div class="post-metadata">

**Author:** ![olzama](https://delphinqa.ling.washington.edu/user_avatar/delphinqa.ling.washington.edu/olzama/32/6_2.png) [@olzama](https://delphinqa.ling.washington.edu/u/olzama)\
**Post date:** [November 20, 2019, 7:08pm UTC](https://delphinqa.ling.washington.edu/t/relations-lost-in-adjunct-extraction-with-alists-emerson-lists/373/2 "2019-11-20T19:08:59Z")

</div>

…What I probably should be inspecting though is the RELS lists.

I still have the following (good) RELS on the head daughter of the filler-gap rule:

 ![13%20AM](https://delphinqa.ling.washington.edu/uploads/default/original/1X/0bb923d5464c7661d7f5b164fe643b697ff0d214.jpeg)

So, the problem must be in the filler-gap rule…

---

<div class="post-metadata">

**Author:** ![olzama](https://delphinqa.ling.washington.edu/user_avatar/delphinqa.ling.washington.edu/olzama/32/6_2.png) [@olzama](https://delphinqa.ling.washington.edu/u/olzama)\
**Post date:** [November 20, 2019, 7:24pm UTC](https://delphinqa.ling.washington.edu/t/relations-lost-in-adjunct-extraction-with-alists-emerson-lists/373/3 "2019-11-20T19:24:12Z")

</div>

Here’s where I think the RELS append happens for my filler-gap rule (I will post the full “pedigree” if needed):

```auto
basic-binary-phrase := phrase &
  [ SYNSEM.LOCAL.CONT [ RELS.APPEND < #r1, #r2, #r3 >,
			HCONS.APPEND < #h1, #h2, #h3 >,
			ICONS.APPEND < #i1, #i2, #i3 > ],
    C-CONT [ RELS #r1,
	     HCONS #h1,
	     ICONS #i1 ],
    ARGS < sign & [ SYNSEM.LOCAL local &
				 [ CONT [ RELS #r2,
					  HCONS #h2,
					  ICONS #i2 ] ] ],
	   sign & [ SYNSEM.LOCAL local &
				 [ CONT [ RELS #r3,
					  HCONS #h3,
					  ICONS #i3 ] ] ] > ].

```

So, for some reason looks like #r3 has gone missing? But the binary phrase itself is unlikely to be the culprit because head-subject and head-complement rules inherit from it also, and the MRS of sentences licensed by them look fine.

---

<div class="post-metadata">

**Author:** ![ebender](https://delphinqa.ling.washington.edu/letter_avatar_proxy/v4/letter/e/34f0e0/32.png) [@ebender](https://delphinqa.ling.washington.edu/u/ebender)\
**Post date:** [November 20, 2019, 8:24pm UTC](https://delphinqa.ling.washington.edu/t/relations-lost-in-adjunct-extraction-with-alists-emerson-lists/373/4 "2019-11-20T20:24:11Z")

</div>

At a guess: Does the wh word itself have an Emerson-list-ified RELS value?

---

<div class="post-metadata">

**Author:** ![olzama](https://delphinqa.ling.washington.edu/user_avatar/delphinqa.ling.washington.edu/olzama/32/6_2.png) [@olzama](https://delphinqa.ling.washington.edu/u/olzama)\
**Post date:** [November 20, 2019, 8:51pm UTC](https://delphinqa.ling.washington.edu/t/relations-lost-in-adjunct-extraction-with-alists-emerson-lists/373/5 "2019-11-20T20:51:20Z")

</div>

It does (at least superficially):

```auto
wh-adverb-lex := adverb-lex-item & 
[SYNSEM [ LOCAL.CONT [ RELS.LIST < [], [ARG0 #arg0], quant-relation & [PRED "which_q_rel"] > ],
           NON-LOCAL.QUE.LIST < #arg0 > ] ].

```

Maybe something more is needed here?

---

<div class="post-metadata">

**Author:** ![guyemerson](https://delphinqa.ling.washington.edu/user_avatar/delphinqa.ling.washington.edu/guyemerson/32/540_2.png) [@guyemerson](https://delphinqa.ling.washington.edu/u/guyemerson)\
**Post date:** [November 20, 2019, 9:07pm UTC](https://delphinqa.ling.washington.edu/t/relations-lost-in-adjunct-extraction-with-alists-emerson-lists/373/6 "2019-11-20T21:07:20Z")

</div>

That doesn’t look like a good RELS list to me! Could you zoom out? You need to look at RELS.LIST, which should be an ordinary list. If RELS.LIST is actually the thing at the top of this screenshot ([10] list), then the append is broken, probably because a list is underspecified somewhere.

---

<div class="post-metadata">

**Author:** ![guyemerson](https://delphinqa.ling.washington.edu/user_avatar/delphinqa.ling.washington.edu/guyemerson/32/540_2.png) [@guyemerson](https://delphinqa.ling.washington.edu/u/guyemerson)\
**Post date:** [November 20, 2019, 9:23pm UTC](https://delphinqa.ling.washington.edu/t/relations-lost-in-adjunct-extraction-with-alists-emerson-lists/373/7 "2019-11-20T21:23:46Z")

</div>

On closer inspection, I can see that [12] is of type list-copy, when it should be either cons-copy or null-copy. My guess is that the C-CONT is underspecified.

---

<div class="post-metadata">

**Author:** ![olzama](https://delphinqa.ling.washington.edu/user_avatar/delphinqa.ling.washington.edu/olzama/32/6_2.png) [@olzama](https://delphinqa.ling.washington.edu/u/olzama)\
**Post date:** [November 20, 2019, 9:45pm UTC](https://delphinqa.ling.washington.edu/t/relations-lost-in-adjunct-extraction-with-alists-emerson-lists/373/8 "2019-11-20T21:45:26Z")

</div>

Thank you, Guy!

I will look into C-CONT (I don’t actually remember what it is for and what should happen there).

As for the well-formedness of the lists, does this look good? This belongs to the lowest S node, licensed by the head-subject rule:

 ![41%20PM](https://delphinqa.ling.washington.edu/uploads/default/original/1X/db67399365344e952be60bf3d8863f8febcff396.jpeg)

---

<div class="post-metadata">

**Author:** ![olzama](https://delphinqa.ling.washington.edu/user_avatar/delphinqa.ling.washington.edu/olzama/32/6_2.png) [@olzama](https://delphinqa.ling.washington.edu/u/olzama)\
**Post date:** [November 20, 2019, 9:50pm UTC](https://delphinqa.ling.washington.edu/t/relations-lost-in-adjunct-extraction-with-alists-emerson-lists/373/9 "2019-11-20T21:50:59Z")

</div>

…Constraining the extracted adjunct rule to be C-CONT.RELS.LIST \< \> fixed the MRS :).

This is something that isn’t in the matrix core though, so I am wondering: was this not an issue with diff-lists? We used to have good semantics for extracted adjuncts, I am pretty sure.

---

<div class="post-metadata">

**Author:** ![ebender](https://delphinqa.ling.washington.edu/letter_avatar_proxy/v4/letter/e/34f0e0/32.png) [@ebender](https://delphinqa.ling.washington.edu/u/ebender)\
**Post date:** [November 20, 2019, 9:58pm UTC](https://delphinqa.ling.washington.edu/t/relations-lost-in-adjunct-extraction-with-alists-emerson-lists/373/10 "2019-11-20T21:58:36Z")

</div>

C-CONT is the constructional content i.e. the semantic contribution of the rule. Rules that aren’t adding any RELS should say so. In diff-list land, this would be RELS \<! !\>. Maybe this particular rule didn’t get updated when you switched over?

---

<div class="post-metadata">

**Author:** ![olzama](https://delphinqa.ling.washington.edu/user_avatar/delphinqa.ling.washington.edu/olzama/32/6_2.png) [@olzama](https://delphinqa.ling.washington.edu/u/olzama)\
**Post date:** [November 20, 2019, 10:11pm UTC](https://delphinqa.ling.washington.edu/t/relations-lost-in-adjunct-extraction-with-alists-emerson-lists/373/11 "2019-11-20T22:11:32Z")

</div>

> [@ebender](#):
>
> Maybe this particular rule didn’t get updated when you switched over?

Currently in the matrix core, we have, for the adjunct extraction rule:

```auto
C-CONT [ HOOK #hook,
	     HCONS <! !>,
	     ICONS <! !> ]

```

- nothing about RELS. Used to work, I am pretty sure?..

---

<div class="post-metadata">

**Author:** ![ebender](https://delphinqa.ling.washington.edu/letter_avatar_proxy/v4/letter/e/34f0e0/32.png) [@ebender](https://delphinqa.ling.washington.edu/u/ebender)\
**Post date:** [November 20, 2019, 10:23pm UTC](https://delphinqa.ling.washington.edu/t/relations-lost-in-adjunct-extraction-with-alists-emerson-lists/373/12 "2019-11-20T22:23:32Z")

</div>

Are there subtypes that say something about RELS?

---

<div class="post-metadata">

**Author:** ![olzama](https://delphinqa.ling.washington.edu/user_avatar/delphinqa.ling.washington.edu/olzama/32/6_2.png) [@olzama](https://delphinqa.ling.washington.edu/u/olzama)\
**Post date:** [November 20, 2019, 10:28pm UTC](https://delphinqa.ling.washington.edu/t/relations-lost-in-adjunct-extraction-with-alists-emerson-lists/373/13 "2019-11-20T22:28:32Z")

</div>

Well the unary-phrase is doing the appends. But I don’t think anything says directly that extracted-adj rule is RELS \<! !\>, at least I don’t see that.

---

<div class="post-metadata">

**Author:** ![ebender](https://delphinqa.ling.washington.edu/letter_avatar_proxy/v4/letter/e/34f0e0/32.png) [@ebender](https://delphinqa.ling.washington.edu/u/ebender)\
**Post date:** [November 20, 2019, 10:43pm UTC](https://delphinqa.ling.washington.edu/t/relations-lost-in-adjunct-extraction-with-alists-emerson-lists/373/14 "2019-11-20T22:43:03Z")

</div>

_sub_types

---

<div class="post-metadata">

**Author:** ![olzama](https://delphinqa.ling.washington.edu/user_avatar/delphinqa.ling.washington.edu/olzama/32/6_2.png) [@olzama](https://delphinqa.ling.washington.edu/u/olzama)\
**Post date:** [November 20, 2019, 10:48pm UTC](https://delphinqa.ling.washington.edu/t/relations-lost-in-adjunct-extraction-with-alists-emerson-lists/373/15 "2019-11-20T22:48:34Z")

</div>

Oh I see; I don’t know how it was used before by others; my Russian grammar wasn’t positing any additional constraints, I don’t think. But I’d need to restore from the repository to confirm that (not sure how relevant this is at this point).

---

<div class="post-metadata">

**Author:** ![olzama](https://delphinqa.ling.washington.edu/user_avatar/delphinqa.ling.washington.edu/olzama/32/6_2.png) [@olzama](https://delphinqa.ling.washington.edu/u/olzama)\
**Post date:** [November 20, 2019, 11:00pm UTC](https://delphinqa.ling.washington.edu/t/relations-lost-in-adjunct-extraction-with-alists-emerson-lists/373/16 "2019-11-20T23:00:34Z")

</div>

Update: I went ahead and looked in the old commit, and I am pretty sure I am seeing good semantics with extracted adjuncts and not seeing the RELS \<! !\> constraint anywhere. We can look together some time next week maybe? If that sounds important.

---

<div class="post-metadata">

**Author:** ![guyemerson](https://delphinqa.ling.washington.edu/user_avatar/delphinqa.ling.washington.edu/guyemerson/32/540_2.png) [@guyemerson](https://delphinqa.ling.washington.edu/u/guyemerson)\
**Post date:** [November 21, 2019, 3:43pm UTC](https://delphinqa.ling.washington.edu/t/relations-lost-in-adjunct-extraction-with-alists-emerson-lists/373/17 "2019-11-21T15:43:26Z")

</div>

append-lists aren’t any more likely to break than diff-lists – in both cases, every list needs to be specified. With diff-lists, RELS _must_ be specified to be \<! !\> (rather than an underspecified diff-list), and with append-lists, RELS.LIST _must_ be specified to be \<\> (rather than an underspecified list).

---

<div class="post-metadata">

**Author:** ![olzama](https://delphinqa.ling.washington.edu/user_avatar/delphinqa.ling.washington.edu/olzama/32/6_2.png) [@olzama](https://delphinqa.ling.washington.edu/u/olzama)\
**Post date:** [November 21, 2019, 4:44pm UTC](https://delphinqa.ling.washington.edu/t/relations-lost-in-adjunct-extraction-with-alists-emerson-lists/373/18 "2019-11-21T16:44:42Z")

</div>

Understood; I am trying to figure out now why it seems to me that an older version of the grammar used to work without that constraint… but it is unrelated to the thread actually, so, apologies :).