Using a parametrized list for adjunct extraction ambiguity

[olzama]

Related to this.

I need help with this because I still don’t actually understand how parametrized lists work.

The problem (pseudolanguage):

(Adjunct extraction needs to be able to apply before and after subject extraction, in principle, but we’d like it to apply low with respect to actual realization of the subject.)

What I tried:

; A list of gaps.

gaplist := list.

ogaplist := gaplist & olist.

gapcons := gaplist & cons &
  [ FIRST gap,
    REST  gaplist ].

; OZ can't do that:
;ogapcons := gapcons & ocons.

gapnull := gaplist & null.

ogapnull := gapnull & onull.

And then:

extracted-adj-phrase :+ [ HEAD-DTR.SYNSEM.LOCAL.CAT.VAL.SUBJ gaplist ].

But this does not have the desired effect. I am assuming this might be because some phrasal rules (such as the filler-gap) do not have the right types on the SUBJ but I am not sure what they should do in this respect. Currently filler-gap says SUBJ olist and then in customization it actually becomes < > in the case of this pseudolanguage.

[guyemerson]

What are the rules in the tree?

How is this pseudolanguage supposed to behave?

[guyemerson]

As for parametrised lists, what are you struggling with?

my-list := list.
my-null := my-list & null.
my-cons := my-list & cons &
  [ FIRST special-type,  ; puts a constraint on this element of the list
    REST my-list ].  ; propagates the above constraint through the whole list

[olzama]

Right—

The language is multiple fronting of wh. The rules are, the S over VP is subject extraction. The S over S is adjunct extraction.

(This doesn’t depend on whether this is a single adjunct extraction rule or the hierarchy with PLACEHOLDER, by the way; it happens in both cases without lexical threading. Lexical threading must have been blocking this ambiguity somehow. With PLACEHOLDER, the left tree will have adjunct-first and the right tree adjunct-last.)

[olzama]

I am struggling to think of the next step after I added this list hierarchy and constrained the daughter of adjunct extraction to have SUBJ gaplist (which had no effect). I don’t understand what else to try or why that did not have effect.

[ebender]

I think that solution also depends on the subject extraction rule saying that the daughter’s SUBJ value is a gap (and the overt head-subj rules also unifying in canonical-synsem). Are both of those things happening?

[guyemerson]

I think the problem is that the SUBJ list is empty both before and after the head-filler rule (for “who”), so putting constraints on SUBJ won’t constrain anything.

[ebender]

That too – the constraint should be on the adj-extraction rule.

[olzama]

Current subject extraction rule (yes, it does say the daughter’s SUBJ is a gap):

basic-extracted-subj-phrase := basic-extracted-arg-phrase & head-compositional &
  [ SYNSEM [ LOCAL.CAT.VAL [ SUBJ < >,
                           COMPS #comps,
                           SPEC #spec, SPR #spr ],
             NON-LOCAL.SLASH.APPEND < #slash, [ LIST < #local > ] > ],
    HEAD-DTR.SYNSEM [ LOCAL.CAT [ VAL [ SUBJ < gap &
                                             [ LOCAL local & #local &
                                               [ CONT.HOOK.INDEX ref-ind ] ] >,
                                        SPR #spr, COMPS #comps,
                                        SPEC #spec],
                                  MC na ],
                       NON-LOCAL.SLASH #slash ],
    C-CONT [ RELS.LIST < >,
             HCONS.LIST < >,
             ICONS.LIST < > ] ].

the overt head-subj rules also unifying in canonical-synsem

What does this mean, actually?

Current head-subject rule:

basic-head-subj-phrase := binary-nonloc-phrase & head-compositional &
 [ SYNSEM phr-synsem &
           [ LOCAL.CAT [ WH [ OR < #or1, #or2 > ],
                         HC-LIGHT -,
                         VAL [ SPEC #spec,
                               SUBJ < >,
                               COMPS #comps,
                               SPR #spr ] ],
            MODIFIED #modified ],
    HEAD-DTR.SYNSEM [ LOCAL.CAT [ WH  #or1,
                                VAL [ SPEC #spec, SUBJ < #synsem >,
                                    COMPS #comps,
                                    SPR #spr ] ],
                      MODIFIED #modified ],
    NON-HEAD-DTR.SYNSEM #synsem & canonical-synsem &
           [ LOCAL [ CAT [ WH #or2,
                           VAL [ SUBJ olist,
                                 COMPS olist,
                                 SPR olist ] ] ],
             NON-LOCAL [ SLASH append-list,
                         REL.LIST < > ] ],
    C-CONT [ RELS.LIST < >, HCONS.LIST < >, ICONS.LIST < > ] ].

[olzama]

@ebender

That too – the constraint should be on the adj-extraction rule.

Which constraint, this one? Or something else?

extracted-adj-phrase :+ [ HEAD-DTR.SYNSEM.LOCAL.CAT.VAL.SUBJ gaplist ].

[guyemerson]

Right, so I meant that extracted-adj-phrase :+ [ HEAD-DTR.SYNSEM.LOCAL.CAT.VAL.SUBJ gaplist ]. doesn’t do anything if the SUBJ list is empty. Every constituent above subject extraction has an empty SUBJ.

In the previous analysis, adjunct extraction was forced to be low by making SUBJ non-empty. This doesn’t work if we want to allow the rules to apply in both orders. But there needs to be some other constraint that ensures the extraction rules apply low.

[guyemerson]

I thought that perhaps the LIGHT feature might be useful here, but basic-extracted-arg-phrase currently sets LIGHT -. I’m not sure what phenomena LIGHT is being used for, so this is a very tentative suggestion.

[olzama]

I thought about LIGHT, too. But its meaning is supposed to be that something is more like a word than like a phrase (I think), and I am not sure that is true for an adjunct’s MOD element?

But anyway, I think it will work in this instance! I for some reason thought that the [ LIGHT - ] constraint on the extracted-arg phrase was needed for something (the information structure library uses LIGHT extensively), and yet now I am not seeing any of the other tests fail if I take that constraint out and replace it with passing up LIGHT from the head daughter. So, thanks for suggesting I try it again!

Now I think the only regression ambiguity is this:

(UPDATE: Looks like the below doesn’t really happen with a single adjunct extraction rule; see next post)

In other words, adjunct extraction happily applies before and after subject extraction—in the same sentence, low with respect to actual subject realization. (Full disclosure: this is actually a version with PLACEHOLDER and multiple rules; I am going to try the single-rule version next, but it should be the same situation).

Maybe that’s OK? Interestingly I don’t have such regressions in my Russian test; there I only seem to have lost various ambiguity instances. There are only two regressions (two sentences across all tests): this one and the same one in another multiple fronting pseudolanguage. Perhaps this is close to being in the “a little ambiguity in exchange for a simpler grammar” camp now?

[olzama]

Actually, with the version where I have only one adjunct extraction rule, all tests now pass! (Except for Russian, but that all looks like lost ambiguity at a glance, so, improvement.) That is not a fully merged-with-the-trunk version though, so, a bit more time is needed before victory can be declared, but still!

[olzama]

Improvements across the board in the Russian test! Yay! Thanks, Guy and Emily.